anomly.f

Go to the documentation of this file.

      SUBROUTINE anomly(NFLG,AIN,E,AOUT)
C  VERSION 6/30/86
C  PURPOSE
C    TO CONVERT AMONG MEAN, ECCENTRIC AND TRUE ANOMALY
C  INPUT ARGUMENTS
C    NFLG    = 1, MEAN TO ECCENTRIC
C              2, MEAN TO TRUE
C              3, ECCENTRIC TO MEAN
C              4, ECCENTRIC TO TRUE
C              5, TRUE TO MEAN
C              6, TRUE TO ECCENTRIC
C    AIN     = INPUT ANGLE (RAD)
C    E       = ECCENTRICITY
C  OUTPUT ARGUMENT
C    AOUT    = OUTPUT ANGLE (RAD)
C  CALL SUBROUTINES
C    KEPLER
C  REFERENCE
C    JPL EM 312/87-153, 20 APRIL 1987
C  ANALYSIS
C    JOHNNY H. KWOK
C  PROGRAMMER
C    JOHNNY H. KWOK
C  MODIFICATIONS
C    NONE
C  COMMENTS
C    NONE
C
      IMPLICIT DOUBLE PRECISION (a-h,o-z)
      DATA one,two/1.d0,2.d0/
      GO TO (11,11,12,12,13,13) nflg
   11 am=ain
      GO TO 14
   12 ea=ain
      GO TO 14
   13 f=ain
   14 CONTINUE
      IF (nflg.EQ.1.OR.nflg.EQ.2) CALL kepler(am,e,ea,se,ce)
      IF (nflg.EQ.1) GO TO 900
      IF (nflg.EQ.2.OR.nflg.EQ.4) THEN
        f=two*datan(dsqrt((one+e)/(one-e))*dtan(ea/two))
        GO TO 900
      ENDIF
      IF (nflg.EQ.5.OR.nflg.EQ.6)
     1  ea=two*datan(dsqrt((one-e)/(one+e))*dtan(f/two))
      IF (nflg.EQ.6) GO TO 900
      IF (nflg.EQ.5.OR.nflg.EQ.3) THEN
        am=ea-e*dsin(ea)
        GO TO 900
      ENDIF
  900 CONTINUE
      GO TO (21,22,23,22,23,21) nflg
   21 aout=ea
      GO TO 24
   22 aout=f
      GO TO 24
   23 aout=am
   24 CONTINUE
      RETURN
      END