esdist.f

Go to the documentation of this file.

 
        real*8 function esdist(iyr,iday,msec)
c
c  this subroutine computes the earth-sun distance in au. it uses the model 
c  referenced in the astronomical almanac for 1984, section s(supplement).
c
c       arguments:
c
c       name    Type    i/o     description
c       --------------------------------------------------------
c       iyr     i*4      i      year, four digits(i.e, 1993)
c       iday    i*4      i      day of year(1-366)
c       msec    i*4      i      milliseconds of day 
c       rs      r*4      o      magnitude of the sun vector(au)
c
c       subprograms referenced:
c
c       jd              computes julian day from calendar date
c
c       coded by:  frederick s. patt, gsc, november 2, 1992
c       adapted from sun2000 to esdist by b. franz, oct 2003.
c
        implicit none
        integer*4 iyr, iday, msec, jd
        real*8    t, gs
c
        real*8    radeg
        integer*4 imon
c
        data radeg /57.29577951/
        data imon  /1/
 
 
c   compute floating point days since jan 1.5, 2000 
c   note that the julian day starts at noon on the specified date
 
        t = jd(iyr,imon,iday) 
     *    - 2451545.0d0 
     *    + (msec/1000.d0 - 43200.d0)/86400.d0
 
c  compute mean anomaly
 
        gs = 357.52772d0 + 0.9856002831d0*t
 
c  compute solar distance(au)
        esdist = 1.00014d0 - 0.01671d0*cos(gs/radeg) 
     *         - 0.00014d0*cos(2.0d0*gs/radeg)
 
        return
        end