NASA Ocean Color

ocssw V2022

 c       data set invert (entered from hardcopy, 10 Jan 93, JWhiting)
       subroutine invert(a,b,n,l,c,ier)
  
 c  invert -- inverts a matrix in place and solves a set of 
 c            simultaneous linear equations.
  
 c  input: 
  
 c  a(l,l)    matrix to be inverted (inverse is returned in this 
 c            same array).
 c  b(n)      vector of right hand sides of linear equations
 c  n         number of equations to be solved (1-20)
 c  l         dimension of a, as declared in calling prog (l.ge.n)
  
 c  output:
  
 c  a(l,l)    inverse of original matrix
 c  c(n)      vector of solution to linear equations
 c  ier       return code
 c            =0, normal return
 c            =1, singular matrix (matrix a may be altered)
 c            =2, invalid input (n.lt.1, or n.gt.20, or l.lt.n)
 c                (matrix a unaltered)
  
 c  external references: none
  
 c    M. Shear, Computer Sciences Corp. 3-30-75
 c    Minor revision to subroutine LINEAR. Name changed and error 
 c    return ier=2 inserted.  January 1976
  
 c  Method
 c    Gauss-Jordan elimination with normalization and optimal pivoting.
  
 c  Reference
 c    Shan S. Kuo, Numerical Methods and Computers, 
 c    Addison-Wesley, 1965. pp. 168-169.
  
 c  Notes
 c    1. If only matrix inversion is desired, the vector of right hand 
 c       sides may be set to zeroes.
 c    2. Execution time varies approx. as n**3. For n=20, execution 
 c       time is about .1 seconds (IBM S/360-95)
  
       implicit real*8 (a-h,o-z)
       dimension a(l,l), b(1), c(1)
  
 c Internal declarations
       dimension ipvot(20), index(20,2)
  
 c Initialize
       if (n.lt.1 .or. n.gt.20 .or. l.lt.n) goto 902
       do 10 i=1,n
         c(i)=b(i)
    10 ipvot(i)=0
  
 c Loop on eliminations
       do 500 npass=1,n
  
 c Determine pivot element
         amax=0.d0
         do 30 j=1,n
           if (ipvot(j).ne.0) goto 30
           do 20 k=1,n
             if (ipvot(k).ne.0) goto 20
             if (dabs(amax).ge.dabs(a(j,k))) goto 20
             irow=j
             icol=k
             amax=a(j,k)
    20     continue
    30   continue
         if (amax.eq.0.d0) goto 900
         ipvot(icol)=1
  
 c Normalization and exchange of rows
         a(irow,icol)=1.d0
         do 40 i=1,n
           t=a(irow,i)
           a(irow,i)=a(icol,i)
    40     a(icol,i)=t/amax
         t=c(irow)
         c(irow)=c(icol)
         c(icol)=t/amax
         index(npass,1)=irow
         index(npass,2)=icol
  
 c Perform elimination
         do 100 i=1,n
           if (i.eq.icol) goto 100
           t=a(i,icol)
           a(i,icol)=0.d0
           c(i)=c(i)-c(icol)*t
           do 90 j=1,n
    90       a(i,j)=a(i,j)-a(icol,j)*t
   100   continue
   500 continue
  
 c Reorder the inverted matrix by exchanging columns
       do 600 i=1,n
         k=n-i+1
         irow=index(k,1)
         icol=index(k,2)
         do 550 j=1,n
           t=a(j,irow)
           a(j,irow)=a(j,icol)
   550     a(j,icol)=t
   600 continue
       ier=0
       goto 999
  
   900 ier=1
       goto 999
  
   902 ier=2
  
   999 return
       end

index

an array had not been initialized Several spelling and grammar corrections were which is read from the appropriate MCF the above metadata values were hard coded A problem calculating the average background DN for SWIR bands when the moon is in the space view port was corrected The new algorithm used to calculate the average background DN for all reflective bands when the moon is in the space view port is now the same as the algorithm employed by the thermal bands For non SWIR changes in the averages are typically less than Also for non SWIR the black body DNs remain a backup in case the SV DNs are not available For SWIR the changes in computed averages were larger because the old which used the black body suffered from contamination by the micron leak As a consequence of the if SV DNs are not available for the SWIR the EV pixels will not be the granule time is used to identify the appropriate tables within the set given for one LUT the first two or last two tables respectively will be used for the interpolation If there is only one LUT in the set of it will be treated as a constant LUT The manner in which Earth View data is checked for saturation was changed Previously the raw Earth View DNs and Space View DNs were checked against the lookup table values contained in the table dn_sat The change made is to check the raw Earth and Space View DNs to be sure they are less than the maximum saturation value and to check the Space View subtracted Earth View dns against a set of values contained in the new lookup table dn_sat_ev The metadata configuration and ASSOCIATEDINSTRUMENTSHORTNAME from the MOD02HKM product The same metatdata with extensions and were removed from the MOD021KM and MOD02OBC products ASSOCIATEDSENSORSHORTNAME was set to MODIS in all products These changes are reflected in new File Specification which users may consult for exact the pow functions were eliminated in Emissive_Cal and Emissive bands replaced by more efficient code Other calculations throughout the code were also made more efficient Aside from a few round off there was no difference to the product The CPU time decreased by about for a day case and for a night case A minor bug in calculating the uncertainty index for emissive bands was corrected The frame index(0-based) was previously being used the frame number(1-based) should have been used. There were only a few minor changes to the uncertainty index(maximum of 1 digit). 3. Some inefficient arrays(Sigma_RVS_norm_sq) were eliminated and some code lines in Preprocess_L1A_Data were moved into Process_OBCEng_Emiss. There were no changes to the product. Required RAM was reduced by 20 MB. Now

invert

subroutine invert(a, b, n, l, c, ier)

Definition: invert.f:3