euler.f

Go to the documentation of this file.

        subroutine euler(a,xm)
c  computes coordinate transformation matrix corresponding to euler 
c  sequence.  the order of angles in the input array is yaw, roll, 
c  pitch; according to osc, the order of the rotations is the reverse
c  of this; the roll and pitch angles are about the negative y and z
c  axes, respectively, while the yaw angle is about the positive x axis. 
 
c  reference:  wertz, appendix e; osc, personal communication 
 
c  calling arguments
 
c  name         Type    i/o     description
c
c  a(3)         r*4      i      input array of euler angles(degrees)
c  xm(3,3)      r*4      o      output transformation matrix
c
c  frederick s. patt, gsc, sometime in 1992.
c
c  modification history:
c
c
c  modified to change order of rotations to pitch, roll, yaw(-z, -y, -x)
c  f. s. patt, gsc, september 29, 1996.
 
        real xm1(3,3),xm2(3,3),xm3(3,3),xm(3,3),xmm(3,3),a(3)
        radeg = 180.d0/3.14159265359d0
 
c  initialize all matrix elements to zero.      
        do i=1,3
          do j=1,3
            xm1(i,j) = 0.d0
            xm2(i,j) = 0.d0
            xm3(i,j) = 0.d0
          end do
        end do
 
c  compute sines and cosines; use negative of y and z rotations
        c1=cos(a(1)/radeg)
        s1=sin(a(1)/radeg)
        c2=cos(a(2)/radeg)
        s2=-sin(a(2)/radeg)
        c3=cos(a(3)/radeg)
        s3=-sin(a(3)/radeg)
 
c  convert individual rotations to matrices
        xm1(1,1)=1.d0
        xm1(2,2)=c1
        xm1(3,3)=c1
        xm1(2,3)=s1
        xm1(3,2)=-s1
        xm2(2,2)=1.d0
        xm2(1,1)=c2
        xm2(3,3)=c2
        xm2(3,1)=s2
        xm2(1,3)=-s2
        xm3(3,3)=1.d0
        xm3(2,2)=c3
        xm3(1,1)=c3
        xm3(1,2)=s3
        xm3(2,1)=-s3
 
c  compute total rotation as xm1*xm2*xm3 
        call matmpy(xm2,xm3,xmm)
        call matmpy(xm1,xmm,xm)
        return
        end