ellxfm.f

Go to the documentation of this file.

        subroutine ellxfm(attxfm, att_ang, tilt, p, navctl, smat, coef)
c
c  ellxfm(attxfm, att_ang, tilt, p, navctl, smat, coef)
c
c  purpose: get sensor orientation matrix and scan ellipse 
c           coefficients for navigation of seawifs data
c
c  calling arguments:
c
c  name         Type    i/o     description
c  --------     ----    ---     -----------
c  attxfm       r*4      i      size 3 by 3 attitude transform matrix
c  att_ang      r*4      i      size 3 spacecraft yaw, roll and pitch
c  tilt         r*4      i      tilt angle 
c  p            r*4      i      size 3 spacecraft position from gps
c  navctl       struct   i      controls for processing data
c  smat(3,3)    r*4      o      sensor orientation matrix
c  coef(6)      r*4      o      scan path coefficients
c
c  by: w. robinson, gsc, 29 mar 93
c
c  notes: this is taken from the orient routine by f patt.  the 
c       attitude transform matrix replaces the computation of
c       the same made from the position and velocity(this is done 
c       elsewhere).  what follows is the description of orient
c
c  this subroutine performs a simple calculation of the sensor
c  orientation from the orbit position vector and input values of the
c  attitude offset angles.  the calculations assume that the angles
c  represent the yaw, roll and pitch offsets between the local vertical
c  reference frame(at the spacecraft position) and the sensor frame.
c  sensor tilt angles are assumed to be included in the pitch angle.
c  the outputs are the matrix which represents the transformation from
c  the geocentric rotating to sensor frame, and the coefficients which
c  represent the earth scan track in the sensor frame. 
c
c  the reference ellipsoid uses an equatorial radius of 6378.137 km and
c  a flattening factor of 1/298.257 (wgs 1984). 
c
c  modification history:
c
c  added sensor offset matrix navctl.msenoff to calculation of sensor
c  transformation matrix - f. s. patt, march 11, 1994.
c
c       subprograms called:
c
c       crossp          compute cross product of two vectors
c       euler           compute matrix from euler angles
c       matmpy          multiply two 3x3 matrices
c
      implicit none
#include "nav_cnst.fin"
#include "navctl_s.fin"
        type(navctl_struct) :: navctl
 
        real att_ang(3), attxfm(3,3)
        real smat(3,3),coef(6), p(3)
c
        real*8 rd
        real*4 sm1(3,3), sm2(3,3), sm3(3,3), tilt
        integer*4 i, j
 
        rd = 1.d0/omf2
 
c  convert euler angles to matrix
        call euler(att_ang,sm1)
 
c   apply attitude offset matrix 
        call matmpy(sm1,attxfm,sm2)
 
c   apply sensor offset matrix
        call matmpy(navctl%msenoff,sm2,sm1)
 
c  compute rotation matrix for tilt angle and apply
        call eaxis(navctl%tiltcos,tilt,sm2)
        call matmpy(sm2,sm1,sm3)
 
c  compute coefficients of intersection ellipse in scan plane
        coef(1) = 1.d0+(rd-1.d0)*sm3(1,3)*sm3(1,3)
        coef(2) = (rd-1.d0)*sm3(1,3)*sm3(3,3)*2.d0
        coef(3) = 1.d0+(rd-1.d0)*sm3(3,3)*sm3(3,3)
        coef(4) = (sm3(1,1)*p(1)+sm3(1,2)*p(2)+sm3(1,3)*p(3)*rd)*2.d0
        coef(5) = (sm3(3,1)*p(1)+sm3(3,2)*p(2)+sm3(3,3)*p(3)*rd)*2.d0
        coef(6) = p(1)*p(1)+p(2)*p(2)+p(3)*p(3)*rd-re*re
 
c  transfer sensor orientation matrix to output array
        do i=1,3
            do j=1,3
                smat(i,j) = sm3(i,j)
            end do
        end do
 
        return
        end